cmake_minimum_required(VERSION 3.20)
project(easynav_costmap_common)

if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(ament_cmake REQUIRED)
find_package(easynav_common REQUIRED)
find_package(nav_msgs REQUIRED)
find_package(rclcpp REQUIRED)
find_package(geometry_msgs REQUIRED)
find_package(tf2_geometry_msgs REQUIRED)


add_library(${PROJECT_NAME} SHARED
  src/easynav_costmap_common/costmap_2d.cpp
)
target_include_directories(${PROJECT_NAME} PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include/${PROJECT_NAME}>
)
target_link_libraries(${PROJECT_NAME} PUBLIC
  easynav_common::easynav_common
  ${nav_msgs_TARGETS}
  rclcpp::rclcpp
  ${geometry_msgs_TARGETS}
  tf2_geometry_msgs::tf2_geometry_msgs
)

install(
  DIRECTORY include/
  DESTINATION include/${PROJECT_NAME}
)

install(TARGETS
  ${PROJECT_NAME}
  EXPORT export_${PROJECT_NAME}
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib
  RUNTIME DESTINATION lib/${PROJECT_NAME}
)

if(BUILD_TESTING)
  find_package(ament_lint_auto REQUIRED)
  # Files derived from ROS / Nav2 keep their original copyright and license
  list(APPEND AMENT_LINT_AUTO_EXCLUDE ament_cmake_copyright)
  ament_lint_auto_find_test_dependencies()
  # Humble's ament_copyright does not recognize the license with the EasyNav line in the header
  if(NOT "$ENV{ROS_DISTRO}" STREQUAL "humble")
    find_package(ament_cmake_copyright REQUIRED)
    ament_copyright(EXCLUDE
      include/easynav_costmap_common/cost_values.hpp
      include/easynav_costmap_common/costmap_2d.hpp
      include/easynav_costmap_common/occ_grid_values.hpp
      src/easynav_costmap_common/costmap_2d.cpp
      tests/costmap_bresenham_2d.cpp
    )
  endif()

  find_package(ament_cmake_gtest REQUIRED)
  add_subdirectory(tests)
endif()

ament_export_include_directories("include/${PROJECT_NAME}")
ament_export_libraries(${PROJECT_NAME})
ament_export_targets(export_${PROJECT_NAME})
ament_export_dependencies(
  easynav_common
  # pluginlib
  nav_msgs
  rclcpp
  geometry_msgs
  tf2_geometry_msgs
)
ament_package()
